おはようございます！
今回はoutlook2013の裏技を。
メールの送信ボタンを押すときにプログラムが組めるって知ってますか？？
会社のメールのルールで件名には任意の文字列を入れる！とか、
ＣＣに管理職を入れないと外部に添付メールが送れない！とかありませんか？
これを送信前にチェックしてくれる、
私が使っているプログラムをご紹介します！
◇とりあえずプログラムはこちら
↓↓以下、コピー
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'エラー対応
On Error GoTo Exception
'変数宣言
Dim strCC As String
'通常の送信画面か確認（通常の送信画面のみ処理を実行）
If Item.Class = olMail Then
'CCの全ての文字を代入
strCC = Item.CC
'件名に任意の文字が含まれているかチェック
If InStr(Item.Subject, "◇◇") = 0 Then '◇◇が含まれているか？
'文字が含まれいない場合のメッセージ(YesNo)
If MsgBox("メールタグがありません。そのまま送信しますか？", vbCritical + vbYesNo, "タグチェック") <> vbYes Then
'いいえが選択された場合は、送信キャンセル
Cancel = True
Exit Sub
End If
End If
'CCに任意のアドレスが含まれているかチェック
If Item.Attachments.Count > 0 And InStr(strCC, "●●") = 0 Then '●●が含まれているか？
'任意のアドレスが含まれていない場合のメッセージ(YesNo)
If MsgBox("添付ファイルがあります。●●をCCに入れずに送信しますか？", vbCritical + vbYesNo, "CCチェック") <> vbYes Then
'いいえが選択された場合は、送信キャンセル
Cancel = True
Exit Sub
End If
End If
End If
Exit Sub
'エラーだったら・・・
Exception:
'エラーメッセージを表示。
MsgBox CStr(Err.Number) & ":" & Err.Description, vbOKOnly + vbCritical
'送信キャンセル
Cancel = True
Exit Sub
End Sub
↑↑コピーここまで
◇詳細はこちら
■確認メッセージが表示される条件
①件名にタグ("◇◇")がない場合。
②添付ファイルがあり、CCに"●●"が含まれていない場合。
※メッセージは「はい」「いいえ」方式になっており、「はい」なら無視して送信、
「いいえ」なら送信がキャンセルされます。
■動作確認環境
Outlook 2013
■手順
１.マクロのセット
(1)開発タブを表示する。(表示されていない場合のみ)
①[ファイル]タブを選択する。
②[オプション]を選択する。
③[リボンのユーザー設定]を選択する。
④[開発]にチェックを付ける。
⑤[OK]ボタンを押す。
(2)VBAプログラムをセットする。
①[開発]タブを選択する。
②[Visual Basic]を選択する。
③画面左上の[Project1(VbaProject.OTM)]の[+]ボタンを押す。
④[Microsoft Outlook Objects]の[+]ボタンを押す。
⑤[ThisOutlookSession]をダブルクリックする。
⑥画面右に開いた入力欄に上部プログラムをコピーして貼り付ける。
⑦画面上部[デバッグ]タブの[Project1のコンパイル]を押す。
⑧画面左上の[上書き保存](フロッピー)ボタンを押す。
⑨ウインドウを閉じる。
２．マクロの設定(マクロを使えるようにする)
(1)セキュリティ設定の変更をする。
①[ファイル]タブを選択する。
②[オプション]を選択する。
③[セキュリティ センター]を選択する。
④画面右下[セキュリティ センターの設定]ボタンを押す。
⑤[マクロの設定]を選択する。
⑥[すべてのマクロに対して警告を表示する]を選択する。
⑦[OK]ボタンを押す。
■その他注意事項
マクロの設定を[すべてのマクロに対して警告を表示する]としたので
Outlook起動時に毎回セキュリティに関する通知(メッセージボックス)が表示されます。
[マクロを有効にする]を選択して起動してください。
◇あとがき
いかがですか？使えそうですかね？？
何かセキュリティで厳しくなっている現代。
面倒なことが多いですが、チェックはプログラムに任せて少しでも楽にして
本来の業務をする時間を確保しましょう！
◇おすすめ記事
青山辞書: 【これで解決！】 Excel2013の基本と裏ワザ リンク集